|
|
|
 |
|
|
時系列分析ソフトウェア
RATS |
|
3-9. RATS Basics: Other Estimation Techniques
We've already introduced instructions for estimate OLS, ARIMA, and (in the forecast section) VAR models. Now we'll quickly demonstrate just a few of the other estimation techniques available in RATS.
Subsample Regressions
The SMPL option (available on most estimation instructions) allows you to use dummy variables to select subsamples for an estimation. Suppose we have a variable called AGE that contains the age (in years) of a group of survey respondents. We can use logical expressions to create one-zero dummy variables dividing our group into a younger group (30 and under) and an older group (30 and over). The first regression includes only those people in the younger bracket, while the second regression includes only those in the older bracket.
SET UNDER = AGE<=30
SET OVER = AGE>30
LINREG(SMPL=UNDER) Y
# X1 X2 X3
LINREG(SMPL=OVER) Y
# X1 X2 X3
Seemingly Unrelated Regressions
This simple example defines two equations (called GEEQ and WESTEQ) and estimates them using the SUR instruction, which does seemingly unrelated regressions:
EQUATION GEEQ IGE
# CONSTANT FGE CGE
EQUATION WESTEQ IWEST
# CONSTANT FWEST CWEST
SUR 2
# GEEQ
# WESTEQ
Non-linear Least Squares
The following example uses non-linear least squares to estimate the CES production function. The NONLIN instruction defines the parameters to be estimated, the FRML instruction defines the non-linear formula, and NLLS does the estimation (Q is the dependent variable, K and L are the other variables).
NONLIN LGAMMA DELTA NU RHO
FRML CES = LGAMMA-NU/RHO * LOG(DELTA * K**(-RHO) + (1.-DELTA) * L**(-RHO) )
NLLS(FRML=CES) Q
Maximum Likelihood Estimation
This estimates a GARCH(1,1) model using maximum likelihood estimation. We use LINREG to get OLS initial estimates. We then use MAXIMIZE with the Simplex method to get the process started in the right direction. The second MAXIMIZE uses the BHHH (Berndt, Hall, Hall, and Hausman) method to get final estimates. Because RATS allows you to specify the model and the form of the log-likelihood function explicitly, you can implement just about any of the popular ARCH and GARCH variations, including exponential GARCH models, and models with non-normal distributions.
DECLARE SERIES U H
NONLIN B0 VC VA VB
FRML RESID = Y - B0
FRML HF = VC + VA*H{1} + VB*U{1}**2
FRML LOGL = (H(T)=HF(T)),(U(T)=RESID(T)), $
-.5*(LOG(H(T))+U(T)*U(T)/H(T))
LINREG(NOPRINT) Y / U
# CONSTANT
COMPUTE B0=%BETA(1)
COMPUTE VC=%SEESQ,VA=.05,VB=.05
SET H = %SEESQ
MAXIMIZE(METHOD=SIMPLEX,ITERS=5,NOPRINT) LOGL GSTART GEND
MAXIMIZE(METHOD=BHHH,RECURSIVE,ITERS=100) LOGL GSTART GEND
|
|
|
|
| ←RATSのTopページに戻る |
|
|
